Maximum likelihood MNAR selection model

TITLE:

section 10.18 data analysis example 2: mnar selection model;

DATA:

file is depression.dat;

VARIABLE:

! txgroup = condition (0 = control, 1 = treatment);

! dep1-dep3 = wave 1 - wave 3 depression scores;

! r2 = wave 2 missing indicator (0 = complete, 1 = missing);

! r3 = wave 3 missing indicator (0 = complete, 1 = missing, -99 previously missing);

! patt = missingness pattern (1 = wave 2 dropout, 2 = wave 3 dropout, 3 = completer);

! dropout = dropout indicator (0 = completer, 1 = dropout);

names = txgroup dep1 - dep3 r2 r3 patt dropout;

usevariables = txgroup dep1 - dep3 r2 r3; 

missing = all (-99);

categorical are r2 r3;  ! missingness indicators as categorical;

ANALYSIS:

estimator = mlr;  ! FIML with robust standard errors;

integration = montecarlo;  ! monte carlo integration;

MODEL:

icept slope | dep1@0 dep2@1 dep3@2;  ! linear growth model;

icept on txgroup (b3);  ! ( ) parameter labels used by model constraint command;

slope on txgroup (b4);

icept (iceptvar); 

slope; 

icept with slope;

dep1-dep3 (resvar);

! logistic regressions;

r2 on dep1 (2);  ! indicators regressed on outcome at previous waves;

r3 on dep2 (2);

r2 on dep2 (3);  ! indicators regressed on outcome at current wave; 

r3 on dep3 (3);

r2 on txgroup (4);  ! indicators regressed on treatment group; 

r3 on txgroup (4);

MODEL CONSTRAINT:

new(meandiff effsize);  ! new parameters not in the model;

meandiff = b3 + 2*b4;  ! endpoint mean difference and effect size;

effsize = meandiff / sqrt(iceptvar + resvar);

OUTPUT:

sampstat

Questions or suggestions? Email Craig Enders