Maximum likelihood moderated regression with incomplete predictors and interaction

DATA:

file = conscientiousness.dat;

VARIABLE:

names = agree consc jobperf;

usevariables = x z xz y; 

missing = all (-99);

DEFINE:

x = consc;  ! define X as conscientiousness;    

z = agree;  ! define Z as agreeableness;

xz = x*z;  ! compute product term;     

y = jobperf;  ! define Y as job performance; 

ANALYSIS: 

estimator = mlr; ! FIML (the default) with robust standard errors; 

MODEL:

latentx by x@1;  ! fix loadings to 1;              

latentz by z@1;

latentxz by xz@1;

x@0; z@0; xz@0;  ! fix residual variances to 0;   

latentx by xz (latxbyxz);  ! cross-loadings;      

latentz by xz (latzbyxz);

[x] (xmean);  ! predictor variable means (measurement intercepts);                 

[z] (zmean);

[xz];

[latentx] (lxmean);  ! latent variable means;                 

[latentz] (lzmean);

[latentxz] (lxzmean);

latentx latentz latentxz;  ! latent variable variances;

latentx with latentz (covlxlz);  ! latent variable covariances;     

latentx with latentxz;

latentz with latentxz;

y on latentx latentz latentxz;  ! regression;

MODEL CONSTRAINT:

lxmean = 0;  ! impose constraints;          

lzmean = 0;

lxzmean = lxmean*lzmean + covlxlz;

latxbyxz = zmean;

latzbyxz = xmean;

OUTPUT:

sampstat standardized;

Questions or suggestions? Email Craig Enders