Maximum likelihood regression analysis with a categorical moderator

TITLE:

section 4.16 data analysis example 3: moderated multiple regression;

DATA:

file = employee.dat;

VARIABLE:

! id = employee id;

! age = employee age;

! tenure = years on the job;

! female = gender (0 = male, 1 = female);

! wbeing = psychological well-being;

! jobsat = job satisfaction

! jobperf = job performance;

! turnover = turnover intentions (0 = no, 1 = yes);

! iq = iq score;

names = id age tenure female wbeing jobsat jobperf turnover iq;

usevariables = jobperf wbeing;

grouping = female (0 = male, 1 = female); ! categorical moderator;

missing are all (-99);

ANALYSIS:

estimator = ml;  ! FIML (the default);

MODEL:

jobperf on wbeing;

wbeing; ! include incomplete predictors;

MODEL MALE:

! (.) are parameter labels for model constraint command;

jobperf on wbeing (b1male); 

[jobperf] (b0male);

MODEL FEMALE:

jobperf on wbeing (b1female);

[jobperf] (b0female);

MODEL CONSTRAINT:

new(b0diff b1diff); ! define new parameters;

b0diff = b0female - b0male; ! gender difference;

b1diff = b1female - b1male; ! slope difference (interaction);

Questions or suggestions? Email Craig Enders