Maximum likelihood regression analysis

TITLE:

section 4.15 data analysis example 2: multiple regression;

DATA:

file = employee.dat;

VARIABLE:

! id = employee id;

! age = employee age;

! tenure = years on the job;

! female = gender (0 = male, 1 = female);

! wbeing = psychological well-being;

! jobsat = job satisfaction

! jobperf = job performance;

! turnover = turnover intentions (0 = no, 1 = yes);

! iq = iq score;

names = id age tenure female wbeing jobsat jobperf turnover iq;

! select variables for analysis;

usevariables = wbeing jobsat jobperf;

! specify missing value code;

missing are all (-99);

ANALYSIS:

! ml missing data handling (the default);

estimator = ml;

MODEL:

! regress jobperf on wbeing and jobsat;

! (b1) and (b2) are labels used to perform wald test;

jobperf on 

  wbeing (b1) 

  jobsat (b2);

! estimate variances of incomplete predictors;

wbeing jobsat;

! estimate covariances among incomplete predictors;

wbeing with jobsat;

MODEL TEST:

! wald test that both regression coefficients = 0;

b1 = 0;

b2 = 0;

OUTPUT:

! standardized gives standardized estimates (stdyx solution);

! sampstat gives em estimates of summary statistics;

standardized(stdyx) sampstat;

Questions or suggestions? Email Craig Enders